* Replications Lake, Hierarchy in International Relations, with countr-year data (Tables 4.1, 6.1-6.3)
* "Lake_HIR_country_year.dta" must be loaded in memory

* TABLE 3.1: Note order of output slightly different than final table in book

sort year

gen var1 = us_SH1995
gen var2 = us_indexmilperpop1995
gen var3 = us_indally
gen var4 = us_EH1995
gen var5 = us_indexreltradep1995
gen var6 = us_indexexchangerate1995
gen var7 = pop
gen var8 = rgdpc_k
gen var9 = majpow
gen var10 = milper
gen var11 = cap

mat A = J(11,11,1)
mat rownames A = "(1) Security Hierarchy Index" "(2) Military Personnel Index" "(3) Independent Alliances Index" "(4) Economic Hierarchy Index" "(5) Relive Trade Index" "(6) Exchange Rate Index" "(7) Population" "(8) Real GDP per capita" "(9) Major Power" "(10) Military Personnel" "(11) CINC"
mat colnames  A = (1) (2) (3) (4) (5) (6) (7) (8) (9) (10) (11)

local a = 1
local b = `a'

while `a' < 12 {

	while `b' < 12 {
		local i = 1950
		local j = 0
				while `i' < 2001 {
				quietly corr var`a' var`b' if year == `i'
				local k = r(rho)
				local j = (`j'*(`i'-1950) + `k') / (`i' - 1949)
				*display `i' "," `k' "
				if `i' == 2000 display "Average of yearly correlation between var`a' and var`b' : " `j'
				if `i' == 2000 {
					mat A[`b',`a'] = `j'
					if `a' ~= `b' mat A[`a',`b'] = .
					}
				local i = `i' + 1
				}
		local b = `b' + 1
		}

	local a = `a' + 1
	local b = `a'
	}

drop var1 var2 var3 var4 var5 var6 var7 var8 var9 var10 var11

matrix list A, nodotz f(%9.2f) title(Convergent and Discriminant Validity: Correlations between Indicators of Security Hierarchy, Economic Hierarchy, and Coercive Capability: 1950-2000 (Figures reflect the average of yearly correlations.))

* models in Table 5.1

tsset ccode year

xtpcse def_eff L.def_eff L.us_SH1995 L.us_EH1995 L.mid2 L.otherallies L.rgdpc_k L.polity2, pairwise corr(ar1)
xtregar def_eff L.def_eff L.us_SH1995 L.us_EH1995 L.mid2 L.otherallies L.rgdpc_k L.polity2, fe
xtpcse def_eff L.def_eff L.us_indexmilperpop1995 L.us_indally L.us_indexexchangerate1995 L.us_indexreltradep1995 L.mid2 L.otherallies L.rgdpc_k L.polity2, pairwise corr(ar1)
xtpcse def_eff L.def_eff L.us_SH1995 L.us_EH1995  L.mid2 L.otherallies L.rgdpc_k L.polity2 L.coldwar L.opec_me L.civwar L.warsaw, pairwise corr(ar1)

* models in Table 5.2

xtpcse def_eff L.def_eff L.us_SH1995 L.us_EH1995 L.mid2 L.otherallies L.rgdpc_k L.polity2 L.cap, pairwise corr(ar1)
xtpcse def_eff L.def_eff L.us_SH1995 L.us_EH1995 L.mid2 L.otherallies L.rgdpc_k L.polity2 L.rgdp, pairwise corr(ar1)
xtpcse def_eff L.def_eff L.us_SH1995 L.us_EH1995 L.mid2 L.otherallies L.rgdpc_k L.polity2 L.majpow, pairwise corr(ar1)
xtpcse def_eff L.def_eff L.us_SH1995 L.us_EH1995 L.mid2 L.otherallies L.rgdpc_k L.polity2 L.pop, pairwise corr(ar1)
xtpcse def_eff L.def_eff L.us_SH1995 L.us_EH1995 L.mid2 L.otherallies L.rgdpc_k L.polity2 L.milper, pairwise corr(ar1)

* models in Table 5.3

tsset ccode year

xi: xtpcse   openc L.us_SH1995 L.us_EH1995 L.openc L.polity2 L.rgdpc_k L.rgdppc_square L.pop_log year i.ccode, corr(ar1) pairwise  
xi: xtpcse   openc L.us_indexmilperpop1995 L.us_indally L.us_indexexchangerate1995 L.us_indexreltradep1995 L.openc L.polity2 L.rgdpc_k L.rgdppc_square L.pop_log  year i.ccode, corr(ar1) pairwise

* Table A.1

sum us_SH1995 us_indexmilperpop1995 us_indally us_EH1995 us_indexexchangerate1995 us_indexreltradep1995 cap civwar coldwar def_eff polity2 rgdpc_k rgdppc_square pop_log majpow warsaw mid2 opec_me milper otherallies pop rgdp openc